'
'	FT-817 Sequencer
'
'	Version 0.1		31 May 2005
'
'	Written by David Smith VK3HZ
'
'	Purpose:
'
'		Interfaces an FT-817 to two transverters.
'		Each transverter has a different IF (2m/70cm) and is connected to front or rear antenna port.
'		The PICAXE activates the PTT to the appropriate transverter depending on the FT-817 band.
'		It also sequences PTT by applying Tx_Inhibit for 100mS during switching to stop the FT-817 
'		from transmitting until all transverter switching has completed. 
'		 
'       Version History:
'		0.1	31/05/05	First attempt
'
'---------------------------------------------------------------------------------------------------------------
'
'                               HARDWARE  CONNECTIONS
'                                   _____________ 	
'               +5V             Vcc|      U      |Gnd   0V
'               Programming   Serin|             |OP0   FT-817 Tx Inhibit	
'               70cm IF PTT     OP4|  PICAXE08M  |IP1   FT-817 Band Select (Analog)	
'               FT-817 Tx Gnd   IP3|_____________|OP2   2m IF PTT	
'
'PICAXE08M I/O pinouts
'                     FUNCTION                Application in this project
'PIN0     (pin 7)     OUT (Serial out)        FT-817 Tx Inhibit
'PIN1     (pin 6)     IN (Analog)             FT-817 Band Select
'PIN2     (pin 5)     OUT                     2m IF PTT
'PIN3     (pin 4)     IN                      FT-817 Tx Gnd
'PIN4     (pin 3)     OUT                     70cm IF PTT 
'SERIAL   (pin 2)     (Serial in)             Programming
'
'---------------------------------------------------------------------------------------------------------------
'
' Define constants
'
symbol PTT_Delay = 100						' Delay between FT-817 Tx Ground and release of Tx Inhibit
'
symbol Band_2m   = 176						' Minimum ADC reading if   2m band selected
symbol Band_70cm = 190						' Minimum ADC reading if 70cm band selected
'
' Define variables
'
symbol Band_Select    = b0		'w0			' FT-817 Band Select ADC reading
'
'---------------------------------------------------------------------------------------------------------------
'
' Initialisation
'
	dirs = %00010101					' Set Pins 0, 2, 4 as Outputs
	pins = %00000000					' Set all outputs low
'
'---------------------------------------------------------------------------------------------------------------
'
' Main Loop
'
' Nothing happens until FT-817 PTT is pressed
'
wait_tx:
	if pin3 = 1 then wait_tx				' Loop waiting for Tx Gnd signal from FT-817
'
' Check FT-817 band setting
'
	readadc 1, Band_Select
'
'****	debug Band_Select					' Show ADC reading  *** Commented Out
'
	if Band_Select < Band_2m   then wait_rx			' Is it 2 or 70?  If not, do nothing
	if Band_Select < Band_70cm then process_2m		' Is it 2?
'
' 70cm
'
	high 4							' Activate 70cm PTT
	goto process_tx
'
' 2m
'
process_2m:
	high 2							' Activate 2m PTT
'
' Hold off FT-817 transmission until switching has settled
'
process_tx:
	pause PTT_Delay						' Wait a while
	high 0							' Allow FT-817 to transmit
'
' Wait until PTT released
'
wait_rx:
	if pin3 = 0 then wait_rx				' Loop waiting for Tx Gnd signal released by FT-817
'
	pins = %00000000					' Set all outputs low again
	goto wait_tx						' Go back and repeat it all again
'
	end